1.3選擇數(shù)據(jù)源

1.4選擇目標(biāo)

1.5

1.6

1.7

1.8

后續(xù)步驟不再附圖，一直點(diǎn)“下一步”按鈕就好。

2、但是當(dāng)要分別在每個表取樣，那就相當(dāng)麻煩了。今天就為大家提供一個脫離office組件的可以將語句結(jié)果導(dǎo)出到Excel的過程，希望會對大家有幫助！

---導(dǎo)出到Excel
---使用說明：
--        1.執(zhí)行時所連接的服務(wù)器決定文件存放在哪個服務(wù)器
--        2.遠(yuǎn)程查詢語句中，要加上數(shù)據(jù)庫名
ALTER PROC ExportFile
     @QuerySql VARCHAR(max)
    ,@Server VARCHAR(20)
    ,@User VARCHAR(20)
    ,@Password VARCHAR(20)
    ,@FilePath NVARCHAR(100) = 'c:\ExportFile.xls'
AS
    DECLARE @tmp VARCHAR(50) = '[##Table' + CONVERT(VARCHAR(36),NEWID())+']'
    BEGIN TRY
        DECLARE @Sql VARCHAR(max),@DataSource VARCHAR(max)='';
        --判斷是否為遠(yuǎn)程服務(wù)器
        IF @Server <> '.' AND @Server <> '127.0.0.1'
            SET @DataSource = 'OPENDATASOURCE(''SQLOLEDB'',''Data Source='+@Server+';User ID='+@User+';Password='+@Password+''').'
        --將結(jié)果集導(dǎo)出到指定的數(shù)據(jù)庫
        SET @Sql = REPLACE(@QuerySql,' from ',' into '+@tmp+ ' from ' + @DataSource)
        PRINT @Sql
        EXEC(@Sql)
       
        DECLARE @Columns VARCHAR(max) = '',@Data NVARCHAR(max)=''
        SELECT @Columns = @Columns + ',''' + name +''''--獲取列名（xp_cmdshell導(dǎo)出文件沒有列名）
            ,@Data = @Data + ',Convert(Nvarchar,[' + name +'])'--將結(jié)果集所在的字段更新為nvarchar（避免在列名和數(shù)據(jù)union的時候類型沖突）
        FROM tempdb.sys.columns WHERE object_id = OBJECT_ID('tempdb..'+@tmp)
        SELECT @Data  = 'SELECT ' + SUBSTRING(@Data,2,LEN(@Data)) + ' FROM ' + @tmp
        SELECT @Columns =  'Select ' + SUBSTRING(@Columns,2,LEN(@Columns))
        --使用xp_cmdshell的bcp命令將數(shù)據(jù)導(dǎo)出
        EXEC sp_configure 'xp_cmdshell',1
        RECONFIGURE
        DECLARE @cmd NVARCHAR(4000) = 'bcp "' + @Columns+' Union All ' + @Data+'" queryout ' + @FilePath + ' -c -T'
        PRINT @cmd
        exec sys.xp_cmdshell @cmd
        EXEC sp_configure 'xp_cmdshell',0
        RECONFIGURE
        EXEC('DROP TABLE ' + @tmp)
    END TRY
    BEGIN CATCH
        --處理異常
        IF OBJECT_ID('tempdb..'+@tmp) IS NOT NULL
            EXEC('DROP TABLE ' + @tmp)
        EXEC sp_configure 'xp_cmdshell',0
        RECONFIGURE
       
        SELECT ERROR_MESSAGE()
    END CATCH

先不要著急使用，該版本是基于xp_cmdshell的，因?yàn)橐獎?chuàng)建文件，所以要保證你的用戶能有文件管理的權(quán)限，通常簡單點(diǎn)的方法就是將sql server的啟動用戶設(shè)置為本地系統(tǒng)用戶

好了，現(xiàn)在我們來執(zhí)行看看：

--查詢分析器連接哪個服務(wù)器，文件就在哪個服務(wù)器上
--本地導(dǎo)出
EXEC dbo.ExportFile @QuerySql = 'select * from sys.objects', -- varchar(max)
    @Server = '.', -- varchar(20)
    @FilePath = N'c:\objects.xls' -- nvarchar(100)

--遠(yuǎn)程導(dǎo)出
EXEC dbo.ExportFile @QuerySql = 'select * from master.sys.objects', -- varchar(max)
    @Server = '192.168.1.52', -- varchar(20)
    @User = 'sa', -- varchar(20)
    @Password = 'sa', -- varchar(20)
    @FilePath = N'c:\52objects.xls' -- nvarchar(100)

執(zhí)行結(jié)果如下，顯示導(dǎo)出條數(shù)，就沒有報錯，再看看你的C盤，多了2個文件就大功告成了：